Principles of Info and Data Management

**Review Division**

Consider two relation instances **A** and **B** in which **A** has (exactly) two fields *x* and *y* and **B** has just one field *y*, with the same domain as in **A**.

* **A/B** is the set of all *x* values such that for every *y* value in (a tuple of) **B**, there is a tuple (*x*, *y*) in **A**.
* For each *x* value in A, consider the set of *y* values that appear in tuples of **A** with that *x* value. If this set contains (all *y* values in) **B**, the *x* value is in the result of **A/B**.

A/B3

|  |
| --- |
| **s#** |
| s1 |

A/B2

|  |
| --- |
| **s#** |
| s1 |
| s4 |

A/B1

|  |
| --- |
| **s#** |
| s1 |
| s2 |
| s3 |
| s4 |

B3

|  |
| --- |
| **p#** |
| p1 |
| p2 |
| p4 |

B2

|  |
| --- |
| **p#** |
| p2 |
| p4 |

B1

|  |
| --- |
| **p#** |
| p2 |

A

|  |  |
| --- | --- |
| **s#** | **p#** |
| s1 | p1 |
| s1 | p2 |
| s1 | p3 |
| s1 | p4 |
| s2 | p1 |
| s2 | p2 |
| s3 | p2 |
| s4 | p2 |
| s4 | p4 |

Find s# that has all of the p# in Bi

**Supplier Example**

**Datalog to relational algebra (from last time)**

suppliers(SID, SName, Address)

parts(PID, PName, Color)

catalog(SID, PID, Cost)

**Find the part names of parts for which there is some supplier**

q1(PName):- parts(PID, PName, \_), catalog(\_, PID, \_).

answer(pname) := πpname(parts ⋈ catalog)

**Find the SIDs of suppliers who supply a red part or a green part**

q2(SID):- suppliers(SID, \_, \_), parts(PID, \_, red), catalog(SID, PID, \_).

q2(SID):- suppliers(SID, \_, \_), parts(PID, \_, green), catalog(SID, PID, \_).

red(sid) := πsid[σcolor=’red’(parts ⋈ catalog ⋈ supplier)]

green(sid) := πsid[σcolor=’green’(parts ⋈ catalog ⋈ supplier)]

answer(sid) := red(sid) ∪ green(sid)

**Find the SIDs of suppliers who supply a red part and a green part.**

q3(SID):- suppliers(SID, \_, \_), parts(PID1, \_, red), catalog(SID, PID1, \_), parts(PID2, \_, green), catalog(SID, PID2, \_).

red(sid) := πsid[σcolor=’red’(parts ⋈ catalog ⋈ supplier)]

green(sid) := πsid[σcolor=’green’(parts ⋈ catalog ⋈ supplier)]

answer(sid) := red(sid) **∩** green(sid)

**Find the name of the suppliers that supply at least 2 parts that cost more than $2 and have red color**

q4(SName):- suppliers(SID, SName, \_), parts(PID1, \_, red), catalog(SID, PID1, Cost1), parts(PID2, \_, red), catalog(SID, PID2, Cost2), Cost1 > 2, Cost2 > 2, \+ PID1 = PID2.

full2(sid, pid2, color2, cost2) := πsid, pid2, color2, cost2[ρpid->pid2, color->color2, cost->cost2(parts ⋈ catalog ⋈ supplier)]

answer(sname) := πsname{σcolor=’red’, color2=’red’, cost>2, cost2>2, pid!=pid2 [(parts ⋈ catalog ⋈ supplier) ⋈ full2]}

**Non-monotone datalog**

**Find the SIDs of suppliers who supply every part**

doNotSupplySomePart(SID):- suppliers(SID, \_, \_), parts(PID, \_, \_), \+ catalog(SID, PID, \_).

q5(SID):- suppliers(SID, \_, \_), \+ doNotSupplySomePart(SID).

answer(sid) := (πsid, pid Catalog)/(πpid Parts)

**Find the SIDs of suppliers who supply every red part or supply every green part**

doNotSupplySomeRedPart(SID):- suppliers(SID, \_, \_), parts(PID, \_, red), \+ catalog(SID, PID, \_).

doNotSupplySomeGreenPart(SID):- suppliers(SID, \_, \_), parts(PID, \_, green), \+ catalog(SID, PID, \_).

q6(SID):- suppliers(SID, \_, \_), \+ doNotSupplySomeRedPart(SID).

q6(SID):- suppliers(SID, \_, \_), \+ doNotSupplySomeGreenPart(SID).

red(sid) := (πsid, pid Catalog)/[πpid (σcolor=’red’ Parts)]

green(sid) := (πsid, pid Catalog)/[πpid (σcolor=’green’ Parts)]

answer(sid) := red(sid) ∪ green(sid)

**Find the SIDs of suppliers who supply only red parts**

supplyOtherThanRed(SID):- suppliers(SID, \_, \_), catalog(SID, PID, \_), \+ parts(PID, \_, red).

q7(SID):- suppliers(SID, \_, \_), parts(PID, \_, red), catalog(SID, PID, \_), \+ supplyOtherThanRed(SID).

red(sid) := πsid[σcolor=’red’(parts ⋈ catalog ⋈ supplier)]

other(sid) := πsid[σcolor!=’red’(parts ⋈ catalog ⋈ supplier)]

answer(sid) := red(sid) **-** other(sid)

**Find the SIDs of suppliers who sell a red part but not a green part**

sellsGreen(SID):- suppliers(SID, \_, \_), parts(PID, \_, green), catalog(SID, PID, \_).

q8(SID):- suppliers(SID, \_, \_), parts(PID, \_, red), catalog(SID, PID, \_), \+ sellsGreen(SID).

red(sid) := πsid[σcolor=’red’(parts ⋈ catalog ⋈ supplier)]

green(sid) := πsid[σcolor=’green’(parts ⋈ catalog ⋈ supplier)]

answer(sid) := red(sid) **-** green(sid)

**Find the SIDs of suppliers who do not supply any green parts**

supplySomeGreenPart(SID):- suppliers(SID, \_, \_), parts(PID, \_, green), catalog(SID, PID, \_).

q9(SID):- suppliers(SID, \_, \_), \+ supplySomeGreenPart(SID).

green(sid) := πsid[σcolor=’green’(parts ⋈ catalog ⋈ supplier)]

all(sid) := πsid(parts ⋈ catalog ⋈ supplier)]

answer(sid) := green(sid) – all(sid)

**Relational algebra to datalog**



